This tune

This tune has these features. Click on any of them to find tunes that match. For a more detailed search, take a look at the kinds of information page.

One title Only 1 transcription Has lots of stepwise movement Has some stepwise movement major G-sharp 4/4 Has chords explore more...

ABC

You can learn more at abcnotation.com.

X:1
%%MIDI chordname m7(b5) 0 3 6 10
T:Birks Works
M:4/4
L:1/8
Q: "Med. Up Swing" 1/4=130  
C:Dizzy Gillespie
Z:Luis Pablo Gasparotto
K:Ab
V:1 name="Alto 1"
%%MIDI program 65
V:2 name="Alto 2"
%%MIDI program 65
V:3 name="Tenor"
%%MIDI program 66
V:4 name="Baritone"
%%MIDI program 67
V:5 name="Piano"
%%MIDI program 1
%
[V:1] F AB        | =Bc B_B AFAB-               | B3 B z F AB-        | B=B-   BF   _B2  AF   |
[V:2] C EF        | ^FG F=F ECEG-               | G3 G z C EF-        | FA-    AC    G2  AF   |
[V:3] F, A,B,     | =B,C B,_B, A,F,A,D-         | D3 D z A, CD-       | DE-    EF,   D2 A,F,  |
[V:4] F,, A,,B,,  | =B,,C, B,,_B,, A,,F,,A,,B,- | B,3 B, z F, A,B,-   | B,=B,- B,F, _B,2 A,F, |
[V:5] F AB        | =Bc B_B AFAB-               | B3 B z F AB-        | B=B-   BF   _B2  AF   |
%
[V:1] z8           || z8                  | z8                 | z8                 | z8                 |
[V:2] z8           || z8                  | z8                 | z8                 | z8                 |
[V:3] z4 z F, A,B, ||=B,CB,_B, A,F,A,B,-  | B,2 A,C z F, A,B,  | =B,CB,_B, A,F,A,B, | z4 z F, A,B,       |
[V:4] z4 z F, A,B, ||=B,CB,_B, A,F,A,B,-  | B,2 A,C z F, A,B,  | =B,CB,_B, A,F,A,B, | z4 z F, A,B,       |
[V:5] "Fm"z8       || "Fm"z8              | "Gm7(b5)"z4 "C7"z4 | "Fm"z8             | "Cm7(b5)"z4 "F7"z4 |
%
[V:1] z8                   | z8                   | z8                 | z4 z F  AB-   |
[V:2] z8                   | z8                   | z8                 | z4 z C  F_G-  |
[V:3] B,=B,B,_B, A,F,A,B,- | B,2 A,=B, z F, A,_B, | =B,CB,_B, A,F,A,B, | z4 z A, CE-   |
[V:4] B,=B,B,_B, A,F,A,B,- | B,2 A,=B, z F, A,_B, | =B,CB,_B, A,F,A,B, | z4 z F, A,B,- |
[V:5] "Bbm7"z8             | "Bbm7"z8             | "Fm"z8             | "Fm"z8        |
%
[V:1] B  B3  z F  AB-   | B  B3  AFEF-       | F3  B-  B3  F    | z4 z F  AB   ||
[V:2] G  _G3  z D  F=G- | G  G3  FCB,C-      | C3  G-  G3  C    | z4 z C  FG   ||
[V:3] E  E3  z A, DD-   | D  D3  CA,G,A,-    | A,3 D-  D3  A,   | z4 z A, CD   ||
[V:4] B, B,3 z F, A,B,- | B, B,3 A,F,E,F,-   | F,3 B,- B,3 F,   | z4 z F, A,B, ||
[V:5] "Abm7"z4 "Db7"z4  | "Gm7(b5)"z4 "C7"z4 | "Fm"z4 "Bbdim"z4 | "Fm"z8       ||
%
[V:1] !segno!=BcB_B    AFAB-     | B2  Ac z  F  AB    | =BcB_B    AFAB     | z4 z F AB          |
[V:2] !segno!AAAG      FCFG-     | G2  FG z  C  FF    | AAAG      FCFG     | z4 z C  FG         |
[V:3] !segno!EFED    CA,CD-      | D2  C=E z A, CD    | EFED      CA,CD    | z4 z A, CD         |
[V:4] !segno!=B,CB,_B, A,F,A,B,- | B,2 A,C z F, A,B,  | =B,CB,_B, A,F,A,B, | z4 z F, A,B,       |
[V:5] !segno!"Fm"z8              | "Gm7(b5)"z4 "C7"z4 | "Fm"z8             | "Cm7(b5)"z4 "F7"z4 |
% 
[V:1] B=BB_B    AFAB-      | B2  A=B   z F  A_B   | =BcB_B    AFAB     | z4 z F  AB-   |
[V:2] FAAF      FDFF-      | F2  FA    z C  FF    | AAAG      FCFG     | z4 z C  F_G-  |
[V:3] DEED      DA,CD-     | D2  CF    z A, CD    | EFED      CA,CD    | z4 z A, CE-   |
[V:4] B,=B,B,_B, A,F,A,B,- | B,2 A,=B, z F, A,_B, | =B,CB,_B, A,F,A,B, | z4 z F, A,B,- |
[V:5] "Bbm7"z8             | "Bbm7"z8             | "Fm"z8             | "Fm"z8        |
%
[V:1] B  B3  z F  AB-   | B  B3  AFEF-       | F3  B-  B3  F    !coda!| z8     |:
[V:2] G _G3  z D  F=G-  | G  G3  FCB,C-      | C3  G-  G3  C    !coda!| z8     |:
[V:3] E  E3  z A, DD-   | D  D3  CA,G,A,-    | A,3 D-  D3 A,    !coda!| z8     |:
[V:4] B, B,3 z F, A,B,- | B, B,3 A,F,E,F,-   | F,3 B,- B,3 F,   !coda!| z8     |:
[V:5] "Abm7"z4 "Db7"z4  | "Gm7(b5)"z4 "C7"z4 | "Fm"z4 "Bbdim"z4 !coda!| "Fm"z8 |:
%
[V:1] "Fm"z8            | "Gm7(b5)"z4 "C7"z4 | "Fm"z8 | "Cm7(b5)"z4 "F7"z4 |
[V:2] "Fm"z8            | "Gm7(b5)"z4 "C7"z4 | "Fm"z8 | "Cm7(b5)"z4 "F7"z4 |
[V:3] "Fm"z8            | "Gm7(b5)"z4 "C7"z4 | "Fm"z8 | "Cm7(b5)"z4 "F7"z4 |
[V:4] "Fm"z8            | "Gm7(b5)"z4 "C7"z4 | "Fm"z8 | "Cm7(b5)"z4 "F7"z4 |
[V:5] "Fm"z8            | "Gm7(b5)"z4 "C7"z4 | "Fm"z8 | "Cm7(b5)"z4 "F7"z4 |
%
[V:1] "Bbm7"z8          | "Bbm7"z8         | "Fm"z8 | "Fm"z8           |
[V:2] "Bbm7"z8          | "Bbm7"z8         | "Fm"z8 | "Fm"z8           |
[V:3] "Bbm7"z8          | "Bbm7"z8         | "Fm"z8 | "Fm"z8           |
[V:4] "Bbm7"z8          | "Bbm7"z8         | "Fm"z8 | "Fm"z8           |
[V:5] "Bbm7"z8          | "Bbm7"z8         | "Fm"z8 | "Fm"z8           |
%
[V:1] "Abm7"z4 "Db7"z4  | "Gm7(b5)"z4 "C7"z4 | "Fm"z8 |1 "Fm"z8 :|2 z4 z F  AB   !D.S.!|]
[V:2] "Abm7"z4 "Db7"z4  | "Gm7(b5)"z4 "C7"z4 | "Fm"z8 |1 "Fm"z8 :|2 z4 z C  FG   !D.S.!|]
[V:3] "Abm7"z4 "Db7"z4  | "Gm7(b5)"z4 "C7"z4 | "Fm"z8 |1 "Fm"z8 :|2 z4 z A, CD   !D.S.!|]
[V:4] "Abm7"z4 "Db7"z4  | "Gm7(b5)"z4 "C7"z4 | "Fm"z8 |1 "Fm"z8 :|2 z4 z F, A,B, !D.S.!|]
[V:5] "Abm7"z4 "Db7"z4  | "Gm7(b5)"z4 "C7"z4 | "Fm"z8 |1 "Fm"z8 :|2 "Fm"z8       !D.S.!|]
%% text Play Ending 1 till last solo
%% text  
[V:1] !coda!z4 z F  AB-   | B  B3  z F  AB-   | B  B3  AFEF-       | F3  B-  B3  F    | z f3 e=d_de- | He8    |]
[V:2] !coda!z4 z C  F_G-  | G  _G3 z D  F=G-  | G  G3  FCB,C-      | C3  G-  G3  C    | z c3 B=A_AA- | HA8    |]
[V:3] !coda!z4 z A, CE-   | E  E3  z A, DD-   | D  D3  CA,G,A,-    | A,3 D-  D3 A,    | z A3 G_GFF-  | HF8    |]
[V:4] !coda!z4 z F, A,B,- | B, B,3 z F, A,B,- | B, B,3 A,F,E,F,-   | F,3 B,- B,3 F,   | z F3 E=D_DC- | HC8    |]
[V:5] !coda!"Fm"z8        | "Abm7"z4 "Db7"z4  | "Gm7(b5)"z4 "C7"z4 | "Fm"z4 "Bbdim"z4 | "Fm"z8       | "Fm"z8 |]

This transcription was found:

• http://abcmr.sourceforge.net/birksworks.abc